Mage Macros

Combat

Living Bomb

For those who have their UI set up to see their focus target and the target's debuffs, this helps you see when living bomb will go off so you can plan a recast.

#showtooltip Living Bomb
/focus
/cast Living Bomb

Anti-chain-fear

For those of you Blood Elves like me out there that can only counter chain fear three times, allowing the fourth one to hit you and the next lock to have full fear power over your toon, This is to help.

/cancelaura Ice Block
/cast [modifier:shift]Counterspell
/cast Ice Block

Left-click to ice block, or shift-click to drop block if you're in it, cast CS, and if ice block is off CD, block. Thus, you can click it out of the first fear then shift click to get right back into it the second they start casting fear again.

this gives you 8 seconds of time before they can fear again... and if specced right, 4 before they can do anything else, either.

Pyroblast or Fireball

Casts Pyro if you're not in combat (as an opener), Fireball otherwise

/cast [nocombat] Pyroblast; Fireball

a slight improvement on the above macro, for button mashers

/castsequence [nocombat] reset=combat Pyroblast, Fireball; Fireball

functions exactly the same way, except that if you are button mashing it won't attempt to cast pyroblast again in that small space before you enter combat after casting.

Another one, defaulting to Pyroblast out of combat, and fireball in combat, but letting you hold alt to switch:

/castsequence [nocombat,modifier:alt] Fireball; [nocombat][combat,modifier:alt] Pyroblast, Fireball; Fireball

Frost Nova
/ Cold Snap

IMPORTANT NOTE: The following macro is bugged as "reset" cannot be used to account for spell cooldowns. This is due to the fact that the reset timer is set back to 0 any time the macro is run. You could therefore continue pressing the button indefinitely and the castsequence would never reset to Frost Nova, because you would be restarting the reset timer with each press. It should be removed but I left it here for reference purposes.

This will cast frost nova on first press. If frost nova is still in cool down it will cast cold snap on second press, and it will cast frost nova on third press. The stop casting is in case you want to use it to interrupt another spell(ie they run in close while casting frost bolt).

/stopcasting
/castsequence reset=21 Frost Nova, Cold Snap

Quick Counterspell

Casts Counterspell immediately, cancelling any spellcast in progress. This helps ensure that you will stop your opponent's cast in time.

#showtooltip Counterspell
/stopcasting
/cast Counterspell

Quick Ice Barrier

Similar to Quick Counterspell, casts Ice Barrier immediately, cancelling any spellcast in progress, allowing you to absorb damage now instead of later.

#showtooltip Ice Barrier
/stopcasting
/cast Ice Barrier

Trinket, then Cast

Pops two trinkets (whatever is in the 13th and 14th inventory slots) and finishes with a damage spell. This boosts DPS by reducing the number of keystrokes or clicks necessary for this common cast sequence.

#showtooltip Frostbolt
/use 13
/use 14
/cast Frostbolt

Each action has the potential to fail (when the trinkets are on cooldown or you lose line of sight on your opponent) and produce an error message and sound. Suppressing these errors makes the macro more pleasant to spam. Below is the version with the error suppression.

#showtooltip Frostbolt
/use 13
/use 14
/script UIErrorsFrame:Clear()
/cast Frostbolt

To disable the annoying error sound you get when your trinkets are on cooldown you can use the following macro (credit to Syrloin on Steamwheedle Cartel):

#showtooltip Frostbolt
/run SetCVar("Sound_EnableSFX","0")
/use 13
/use 14
/run SetCVar("Sound_EnableSFX","1")
/cast Frostbolt

The I Win Button

aka PoM Pyro, the largest burst of damage a mage can deliver. Requires an arcan
/fire spec. Cast the following sequence instantly and with a single button press:

• Presence of Mind, to make Pyroblast an instant cast
• Arcane Power, increasing spell damage and mana consumption by 30% for the next 15 seconds.
• Pop first trinket (probably something that boosts damage or crit)
• Pop second trinket (same deal)
• Pyroblast

No longer needs
/stopcasting after the PoM and AP to get all this to happen with a single button press.

#showtooltip Pyroblast
/cast Presence of Mind
/cast Arcane Power
/use 13
/use 14
/cast Pyroblast

The POM-FROST win button

This is the arcan
/frost version of the previous macro:

#showtooltip Frostbolt
/cast Presence of Mind
/cast Arcane Power
/cast Icy Veins
/use Icon of the Silver Crescent
/cast Frostbolt

=== Experimental Hybrid Mage Win Button This is an interesting macro ,from the experimental Hybrid Mage Build:

/cast Counterspell
/cast Arcane Power
/cast Icy Veins
/use 13/14 [Skull of Gul'dan]
/cast Presence of Mind
/cast Pyroblast

Note : It will nuke the player , and after that you can use Frostbol
/Firebolt.

Anti Grounding Totem Ice Lance

• When used, this macro will cast Ice Lance on the nearest Grounding Totem without you losing your current target.
• If no Grounding Totem exists it will simply cast Ice Lance on your current target. NOTE: while a slight edit will make this a good macro for removing other totems, this macro is absolutely unnecessary for removing grounding totems because grounding totems force harmful spells to target them...that's their purpose.

#showtooltip Ice Lance
/stopcasting
/target [exists] Grounding Totem
/cast Ice Lance
/targetlasttarget

NOTE: Grounding Totem Makes the exact same effect.

Cast on mouseover or target

This macro will attempt to cast Counterspell on your mouseover target. If your mouse is not targeting someone, it will cast Counterspell on your current target instead.

It is also excellent for use with Ice Lance, as well as non-Mage abilities including Earth Shock, Blind, Warlock curses, Feral Charge etc.

#showtooltip Counterspell
/stopcasting
/cast [target=mouseover,exists][target=target,exists] Counterspell

Polymorph

Announce Sheep

"Dude! Quit breaking my sheep!" You've said it before, and you'll say it again. Might as well make it a macro. And since you're already writing a macro, might as well make the announcement *before* they can break your sheep.

This macro will first cast Polymorph, then (if your target was sheepable) announce (in party chat) the name of the mob you're sheeping. If you have no target, if your target is dead or if your target is friendly, you will not successfully sheep nor will you announce the attempt.

/cast Polymorph
/stopmacro [noexists] [dead] [help]
/p Sheeping %t. Back off it.

Sheep Focus

Using focus to keep an eye on your sheep can make you more reliable cc while also maximizing your DPS during the sheep's lifespan. The following macro gives you a single button that automatically manages your sheep as a focus until it dies or until you manually replace it with your current target.

When you click, if you're not already watching a sheep, your current target is put in focus and Polymorphed. Any subsequent clicks will resheep your focus, leaving you free to target something else for damage. Once your sheep is killed, click again to set your current target as focus and sheep it.

If you need to sheep a different target before your current sheep is down, target the new sheep, hold shift and click to make the change.

#showtooltip [target=focus,harm] [] Polymorph
/stopcasting
/clearfocus [modifier:shift][target=focus,dead][target=focus,noexists]
/focus [target=focus,noexists]
/cast [target=focus] Polymorph

Note that using this macro will interrupt any cast in progress and immediately focus and Polymorph.

Full Polymorp
/Focus Macro

This polymorph macro will do the following:

1. Clear your focus if your old focus target is dead
2. Clear your focus if your old focus target doesn't exist anymore
3. Set your focus on what you have targeted if you don't have a focus already
4. Place a Star marker over the head of the focus target (if you are grou
   /raid leade
   /assistant)
5. Polymorph the Focus target
6. Announce the sheeping.

This allows one button to do the whole sheeping process without the need for a separate
/clearfocus button (though an additional macro that does a
/script SetRaidTarget("focus",0) and then a
/clearfocus would be useful to let the group know the sheep is free game now might be useful)

#showtooltip
/clearfocus [target=focus,dead]
/focus [target=focus,noexists]
/script SetRaidTarget("focus", 1)
/cast [target=focus]Polymorph
/stopmacro [nogroup]
/s --== Sheeping and Marking "%t" ==--

As of 2.1, you can also use %f to insert your focus name in chat just like %t inserts your target. Thus, to alert your party that you are sheeping (or re-sheeping) your focus and not your target, try this instead of the last line above:

/s --== Sheeping and Marking "%f" ==--

Target Tracking

This polymorph macro will do the following:

1. Left-Click: Set saved target to current target and sheep it
2. Right-Click: sheep saved target (do not change current focus)
3. Shift-Left-Click: set focus to saved target

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target focus

Target Tracking with Instant Crowd Control Option

This polymorph macro will do the following:

1. Left-Click: Set saved target to current target and sheep it
2. Right-Click: sheep saved target (do not change current focus)
3. Shift-Left-Click (first click): set saved target to focus, cast Presence of Mind
4. Shift-Left-Click (second click): set saved target to focus, sheep it
5. Shift-Right-Click (first click): set focus to saved target, cast Presence of Mind
6. Shift-Right-Click (second click): set focus to saved target, sheep it

/focus [button:1]
/cast [button:1,nomodifier:shift] Polymorph; [target=focus,exists,button:2,nomodifier:shift] Polymorph
/stopmacro [nomodifier:shift]
/target [button:2] focus
/castsequence Presence of Mind, Polymorph

Polymorph with Focus, favouring Mouseover

This is a modified version of the focus-following macros above, that will reset your focus to your mouseover target. This means you can switch polymorph focus without changing your current target.

/clearfocus [target=focus,dead][target=focus,noexists]
/focus [target=mouseover,exists][target=focus,noexists]
/script SetRaidTarget("focus", 1)
/cast [target=focus] Polymorph
/stopmacro [nogroup]
/p --== Sheeping and Marking "%f" ==--

Random

1. If the target can be polymorphed, one of the listed spells will be chosen.
2. If the target can not be polymorphed, stop macro processing.
3. Otherwise, send an emote stating polymorph is in progress.
4. Since 2.3 Polymorph Turle and Pig have been changed from Polymorph: Pig to Polymorph(Rank 1:Pig)
5. In patch 3.0.2 and beyond The spells are named Polymorph(Rank 4), Polymorph(Pig), and Polymorph(Turtle)

/castrandom [harm] Polymorph(Rank 4), Polymorph(Pig), Polymorph(Turtle)
/stopmacro [noharm]
/emote randomly polymorphs %t.

Conjuring, Food and drink

Conjur
/Consume Food, Water, and Gem all in one button

Left click to conjure, right click to consume. Click normally to conjur
/drink water, shift-click to conjur
/eat food, and control-click to conjur
/consume mana gem (replace names of items with whatever the name of what you are currently conjuring is) If you use the ? Icon with this macro, the icon will automatically change based on what buttons you are holding.

/cast [button:1,nomodifier]Conjure Water;[button:1,modifier:shift]Conjure Food;[button:1,modifier:ctrl]Conjure Mana Jade;
/use [button:2,nomodifier]Conjured Spring Water;[button:2,modifier:shift]Conjured Pumpernickel;[button:2,modifier:ctrl]Mana Jade;

Another conjur
/consume foo
/water/gem in one button

A right click will cycle through conjuring food, water, and a mana gem, resetting the cycle after 8 seconds. A right click with shift held will conjure a mana gem, regardless of castsequence position. Left clicking will drink with no modifiers, eat with control, and use the mana gem with shift. Note that this is MUCH more useful with the question mark icon.

/cast [modifier:alt]Conjure Mana Agate
/castsequence [nomodifier,button:2] reset=8 Conjure Water,Conjure Food,Conjure Mana Agate
/stopmacro [button:2]
/use [nomodifier]Conjured Purified Water;[modifier:ctrl]Conjured Rye;[modifier:shift]Mana Agate

Eating and drinking

It's an easy macro if you want to eat and drink with a single click.

/use Conjured Crystal Water
/use Conjured Cinnamon Roll

Eating and drinking no matter the level

If you someetimes replace your food and water with conjured manna biscuits, you may want to refer to the food by bag slot location instead of by name. This will use show the amount and type of food in the 20th slot of the first bag (to the left of the backpack which is zero). Pressing Alt will show and use the slot above it. Clicking it once will use the 20th slot item, clicking it again will use the 16th slot item. If you keep food and water there normally, you'll use them both. If you replace them with Manna Biscuits, it will display and use them instead. If you have different sized bags, adjust the numbers accordingly.

#showtooltip
/cast [modifier:alt][button:2] 1 16
/castsequence [nomodifier:alt, button:1] reset=20 1 20, 1 16

Conjure or ea
/drink

You can condense conjuring and drinking onto a single button using click-logic. In this macro, right-clicks summon water, and left-clicks to use it. The "#showtooltip" command will display the count of waters in your inventory on the button face, unless you are holding down Alt, in which case it will show the spell's tooltip, and if you use the "?" macro icon, it will also show the water-bottle icon and tooltip description on your tool-bar.

#showtooltip [modifier:alt] Conjure Water; Conjured Glacier Water
/cast [button:2] Conjure Water
/use [button:1] Conjured Glacier Water

#showtooltip [modifier:alt] Conjure Food; Conjured Croissant
/cast [button:2] Conjure Food
/use [button:1] Conjured Croissant

Conjure and ea
/drink All-In-One

This is similar to the above macro, but allows Conjuring and Consumption of both food and water from a single button. Clicking activates both Drink and Eat. Right click to conjure Water, and Ctrl+Right click to conjure food. The tooltip will show the number of Conjured Crystal Water you have.

#show Conjured Crystal Water
/cast [button:2,nomodifier] Conjure Water
/cast [button:2,modifier:ctrl] Conjure Food
/use [button:1] Conjured Cinnamon Roll
/use [button:1] Conjured Crystal Water

Conjure foo
/gems and smart ea
/drink All-In-One

This is similar to previous macros, but allows Conjuring of food and gem or Consumption of both food and water from a single button. Clicking uses Manna Biscuit (if avail) or both Drink and Eat. Alt+Right click (5 times) to conjure Water, Food, Gem, Water, Food. Right click to just drink water.

/castsequence [modifier:alt] reset=120 Conjure Water, Conjure Food, Conjure Mana Emerald, Conjure Water, Conjure Food
/stop macro [modifier:alt]
/use Conjured Manna Biscuit
/use Conjured Glacier Water
/stopmacro [button:2]
/use Conjured croissant

Slightly less useful conjure or ea
/drink

this is an easy conjur
/use macro for mages, it needs to be mouse clicked though ( anything after "-" is comments)

#show none - so that your UI don't get confused since we got 2 usable items
/use [nomodifier:alt,button:1] <add conjured food name here> - left click = eat food
/use [nomodifier:alt,button:2] <add conjured water name here> - right click = drink water
/cast [modifier:alt, button:1] Conjure Food - alt+left click = conjure highest rank food
/cast [modifier:alt,button:2] Conjure Water - alt+right click = conjure highest rank water

The same logic can be used for food or mana gems, just substitute the names as appropriate. Obviously, replace with the name of the highest-rank item you can conjure.

Conjure Mana Gems

Patch 3.0.2 changed all mana gems to be unique 1, so you cannot have all rank gems.

If you like to have one button per gem for conjuring and casting you can use this macro for each of your gems. Rightclicking it conjures the gem. Any other way of activating the macro (button press or leftclick or something) uses the gem. Of crouse your replace the gem name with the gem you wanted to use. Downside is that if you use the questionmark icon for the macro, it only shows the gem icon if you have it in your inventory. The gem icon turns into a red questionmark when you log in or zone while not having the gem on you. Hope this gets fixed soon. Alternatively, you can select a fixed macro icon that resembles the gem.

#show Mana Citrine
/cast [button:2] Conjure Mana Citrine
/stopmacro [button:2]
/use Mana Citrine

Merely replacing "#show Mana Citrine" with "#show Conjure Mana Citrine" works as well, however with Mana Emerald it won't show the charges.

Conjur
/Use Mana Gem

This macro will conjure a mana gem if you do not already have one, or use one if you do:

#show Mana Ruby
/use Mana Ruby
/cast [nocombat] Conjure Mana Ruby

Replace "Mana Ruby" with whatever your highest level of mana gem is. The "nocombat" conditional ensures that you do not use the gem then immediately try to conjure another one while you are in a hot situation.

#showtooltip Mana Emerald
/cast [button:1] Conjure Mana Gem
/use [button:2] Mana Emerald

In patch 3.0.2 Blizzard change all the Conjured Mana Gems (Citrine, Ruby, Emerald, etc.) casting names to read just Conjure Mana Gem. The above will conjure the highest Mana Gem you have (In a 70's case it would be the Mana Emerald) by left clicking then will use the Mana Emerald by simply right clicking (Just change Mana Emerald to read whichever Mana Gem you use).

Refresh Mana Emerald

Throws out your current Mana Emerald, recreates a new one with three charges. Saves you from finding your current Emerald in your bags and throwing it out manually if you've used a charge or two and want a new one. (As of patch 3.0.2 this is done automatically. If your Mana Emerald has less than three charges, casting will make it have three charges. If it has three charges it will not cast.)

/run for b=0,4,1 do for s=1,GetContainerNumSlots(b),1 do local n=GetContainerItemLink(b,s) if n and string.find(n,"Mana Emerald") then PickupContainerItem(b,s) DeleteCursorItem() end end end
/cast Conjure Mana Gem

Other utility

Teleporting to Stormwind or Ironforge

This macro is designed to teleport you to Stormwind or Ironforge, and also displays how many runes you have left. Right click = Ironforge Ctrl+Right Click = Stormwind. Enjoy!

#show Rune of Teleportation
/say Teleporting, Cya!
/cast [button:2,nomodifier] Teleport: Ironforge
/cast [button:2,modifier:ctrl] Teleport: Stormwind

Mount and keep going

This macro is designed to let you keep running through stuff you don't want to fight without taking damage (and thus not being Dazed). It will always mount you, but if you are targeting something dangerous, it will put up Mana Shield first.

#show Chestnut Mare Bridle (or whatever your mount item is)
/cast [nomounted,harm] Mana Shield
/stopcasting
/use Chestnut Mare Bridle (or whatever your mount item is)

Buffing

By clicking the left mousebutton you buff yourself, by clicking the right mousebutton you buff your current target (the default way). You can also change the spell ('Arcane Intellect' used in the example) to whatever you like (i.e. 'Remove Lesser Curse').

#Showtooltip Arcane Intellect
/cast [target=player,button:1] Arcane Intellect
/cast [button:2] Arcane Intellect

Alternately you can use this macro for the similar effect. This will cast AI on self on right click, your target on left click, and your target's party if you are in a group (part
/raid) and are holding the ctrl key on left click (mainly useful for not wasting your arcane powder unnecessarily)

#Showtooltip Arcane Intellect
/cast [target=player,button:2] Arcane Intellect
/cast [button:1] Arcane Intellect
/cast [modifier:ctrl,group,button:1] Arcane Brilliance

You can also use this one. Casts AI on left click, AB on right click. Also respects alt selfcast, and shows the amount of arcane powder left on the macro icon. Just select the Arcane Brilliance icon from the macro interface.

#show Arcane Powder
/cast [button:2, modifier:alt, target=player] Arcane Brilliance; [button:2] Arcane Brilliance; [modifier:alt, target=player] Arcane Intellect; Arcane Intellect

Better slow fall

It simply makes you slowfall but it dismounts you first. If you lack the manual dexterity to dismount and then slowfall when you accidentally drop down a cliff, this macro will help you lots. Also, this thing shows the number of light feathers you have left on the macro icon. Note: you will need to press this button twice to dismount and slowfall! Failure to do so in combination with un'goro or flying mounts can have bad consequences.

#show Light Feather
/dismount
/cast Slow Fall

Note that as of Patch 2.1, abilities that previously could not be cast while mounted (such as Slow Fall) will now automatically dismount your player.

Porta
/Teleport on one button

Leftclick teleports you, rightclick summons a portal. The macro shows the amount of teleport stones you have left. Select a custom icon for this one. All the city icons are in the default list. Of course, you adjust the city name to suit your needs.

#show Rune of Portals
/cast [button:2] Portal: Shattrath; Teleport: Shattrath

As of patch 2.1 not only will buttons display the number of reagents available for spells but macros that select different spells will change in real time to show which will be cast. The following macro will teleport you if you are alone and will open a portal if you are in a party or raid, unless you override it by holding down a modifier key (shif
/ctrl/alt). Use the red question mark icon to see which spell will be cast when you use the macro.

/cast [group,nomodifier] Portal: Shattrath; Teleport: Shattrath
/stopmacro [nogroup][modifier]
/p << Shattrath Portal Incoming >>

Porta
/Teleport and announce to Rai
/Party in one button

Leftclick teleports you, rightclick summons a portal, middle button click announces to raid or party that you're creating a portal. Very similar to the macro above.

/cast [button:
/3] Portal: Shattrath; Teleport: Shattrath
/stopmacro [button:
/2] /script local C; if(GetNumRaidMembers()==0) then C = "PARTY" else C = "RAID" end SendChatMessage("Opening Portal to [Shattrath City], Enjoy your trip.", C)

All teleports + hearthstone on one button

Uses one button to cast any teleport; choose by your combination of mod keys. Right-click uses Hearthstone.

#showtooltip
/cast [btn:2]Hearthstone;[mod:ctrl,mod:alt]Teleport: Shattrath;[nomod]Teleport: Ironforge;[mod:shift]Teleport: Stormwind;[mod:ctrl,nomod:alt]Teleport: Darnassus;[mod:alt,nomod:ctrl]Teleport: Exodar

Teleports + Portals + Hearthstone on one button

Uses one button to cast teleport, portal and hearthstone; choose by your combination of mod keys. Middle-click uses Hearthstone.

#showtooltip
/cast [btn:3,nomod]Hearthstone;[btn:1,nomod]Teleport: Stormwind;[mod:shift]Teleport: Ironforge;[mod:ctrl]Teleport: Darnassus;[btn:2]Portal: Stormwind;[btn:2,mod:shift]Portal: Ironforge;[btn:2,mod:ctrl]Portal: Darnassus;

All Portals on one button (Flavor Text)

Uses one button to cast portals to all cities. Easily edited into a separate button for Teleporting.

#showtooltip
/cast [btn:1,nomod]Portal: Orgrimmar;[mod:shift]Portal: Silvermoon;[mod:ctrl,nomod:alt]Portal: Thunder Bluff;[mod:alt,nomod:ctrl]Portal: Undercity;[mod:alt,mod:ctrl]Portal: Shattrath;

Keep your arms and legs inside the portal at all times.

All 3 armors on one button

Left click for Molten Armor, right click for Frost Armor, and alt-click for Mage Armor. Very handy for conserving hotbar space and the like. You can edit the first line to have it display whichever armor's tooltip you prefer, simply change the name of the spell.

#showtooltip Molten Armor;
/cast [button:2] Frost Armor; [nomodifier:alt] Molten Armor; Mage Armor;

This macro is similar, but buffs Molten Armor with left click, Ice Armor with right click, and Mage Armor with middle mouse click (scroll wheel button).

/cast [button:2] Ice Armor; [button:3] Mage Armor; Molten Armor;

Grouping and raiding

Easy Remove Curse Macro

This macro makes it so you can easily remove curses from party members by continually clicking the macro button. The first click will target you, the second will target the closest party member to you. This continues to all party members within range.

For party:

/targetparty
/cast Remove Lesser Curse

For raid:

/targetraid
/cast Remove Lesser Curse

Hover-Target Decurse

This macro comes from the Discord Mods forum and is extremely useful for raiding, allowing you to decurse a member of your part
/raid without having target them. Just hover your mouse over the person's frame in the raid window and hit the key that binds this macro. When using a raid window tuned to show who is in need of decursing (CT Raid comes to mind) this is makes for extremely fast decursing without having to change targets.

/cast [target=mouseover,exists] Remove Lesser Curse

Arcane Spec Macros

With the advent of the arcane spec becoming viable (ABx3->AM->scorc
/fireblast rotation) with 2 part Tirisfal Regalia pieces, not casting while channeling arcane missiles needs to be linked to the vast majority of your spells. This is due to arcane blast being a 7 second "buf
/debuff" therefore only having .5 seconds of latency & downtime between the last two spells of the rotation and again casting arcane blast.

This macro will make it so if you hit the arcane missiles key while casting arcane missiles, nothing happens, but if you are not casting them then you will begin to cast them.

#Showtooltip Arcane Missiles
/cast [nochanneling:Arcane Missiles] Arcane Missiles

This macro allows you to spam a non-channeled spellkey while channeling arcane missiles and not interrupt the channel (trinket included to show you can also add them in)

#Showtooltip Arcane Blast
/use [nochanneling:Arcane Missiles] 13
/cast [nochanneling:Arcane Missiles] Arcane Blast

You should also do this to your scorch an
/or fireblast spells in order to spam them, as casting AM and scorc
/fireblast only gives you .5 seconds to again cast arcane blast before you lose the "buf
/debuff"

Elemental
/ Pet

Some of these ideas are taken from Pet management macros for Warlocks. Having to manually control your 45s pet (or even 1 minute with talents) as a mage is counter productive, he's only around for 45s you should try and maximise his efforts as much as possible.

Frostbolt+Attack

This instructs your pet to stay where he's at and start casting his frostbolt while you cast your frostbolt. You could also cater this macro to any other spells you like.

#showtooltip Frostbolt
/petstay
/petattack
/cast Frostbolt

Petfollow+Frostnova

In my experience when I'm frost nova'ing an area I tend to want to run away from things attacking me there and since a retadin can 3-shot a water elemental it's a good idea to get him out of there too. This combines frost nova
/ petfollow to give you a way to make your elemental to follow you.

#showtooltip Frost Nova
/petfollow
/stopcasting
/cast Frost Nova

Frost Nova and Pet Frost Nova

Very simple macro that makes you cast Pet Frost Nova if normal Frost Nova is on cooldown and hides error messages, incase one of those in on cooldown.

/script UIErrorsFrame:UnregisterEvent("UI_ERROR_MESSAGE");
/cast Frost Nova
/click [pet] PetActionButton5
/script UIErrorsFrame:RegisterEvent("UI_ERROR_MESSAGE");

Combining Petfollow+Frostnova+Freeze

#showtooltip Frost Nova
/petfollow
/stopcasting
/script UIErrorsFrame:UnregisterEvent("UI_ERROR_MESSAGE");
/cast Frost Nova
/click [pet] PetActionButton5
/script UIErrorsFrame:RegisterEvent("UI_ERROR_MESSAGE");

Aggressive+Ice Block

Another good idea is to just let your pet unload on whoever when you iceblock, if you do this though, you may want make a macro or add a
/petdefensive in another spell of yours to switch him back.

#showtooltip Ice Block
/petaggressive
/cast Ice Block

Summon + Buff + Attack

The following is intended to work for 11
/0+/41+ mages. It should summon an elemental on a left click, buff the pet with Focus Magic (hence the 11
/) on right click and have the pet attack your target by left clicking a second time. Obviously, if you are in the group with a more appropriate recipient of Focus Magic or haven't spec'd for that spell, then remove or ignore that section.

#showtooltip Summon Water Elemental
/cast [button:2,target=pet] Focus Magic; [pet] Waterbolt; Summon Water Elemental

Summon + Freeze + Attack + Follow + Stay

This macro summons your elemental and on next press, allows you to cast freeze. If you have a hostile target, your elemental will start attacking it. To use the elemental's second freeze, simply wait for the cooldown to elapse and press the same button again. If you want your elemental to attack a different target but don't want to cast freeze yet, simply right click the screen when the aoe circle appears and you can recast it when you are ready (it doesn't affect your current spell). This is very handy if you want to spam a button to summon, attack and nova something quickly. Alt and shift will set pet to follow or stay.

/castsequence reset=60 summon water elemental, freeze, freeze
/petattack [nomodifier]
/petfollow [modifier:alt]
/petstay [modifier:ctrl]